JDK版本切换

%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit cd /d "%~dp0"
@echo off
echo 当前Java版本
java -version
 
:menu
echo =================================================================================================
echo 请选择要切换的jdk版本
echo 1：Java jdk 1.8
echo 2：Java jdk 11
echo 3：Java jdk 13
echo 0: 取消
echo =================================================================================================
set /p ch=请选择：
if "%ch%"=="1" goto java1.8
if "%ch%"=="2" goto java11
if "%ch%"=="3" goto java13
if "%ch%"=="0" goto exit
goto menu
 
:java1.8
set JAVA_HOME=C:\Program Files\Java\jdk1.8.0_261
set JAVA_VERSION=1.8
goto exec

:java11
set JAVA_HOME=C:\Program Files\Java\jdk-11.0.13
set JAVA_VERSION=11
goto exec
 
:java13
set JAVA_HOME=C:\Program Files\Java\jdk-13.0.2
set JAVA_VERSION=13
goto exec 
 
:exec
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit" /v CurrentVersion /t REG_SZ /f /d "%JAVA_VERSION%"
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment" /v CurrentVersion /t REG_SZ /f /d "%JAVA_VERSION%"
setx "JAVA_HOME" "%JAVA_HOME%" /m
 
del /f "C:\Windows\System32\java.exe"
copy /Y "%JAVA_HOME%\bin\java.exe" "C:\Windows\System32\java.exe"
del /f "C:\Windows\System32\javaw.exe"
copy /Y "%JAVA_HOME%\bin\javaw.exe" "C:\Windows\System32\javaw.exe"
set JAVA32_PATH=C:\Program Files (x86)\Common Files\Oracle\Java\javapath
del /f "%JAVA32_PATH%\java.exe"
mklink "%JAVA32_PATH%\java.exe" "%JAVA_HOME%\bin\java.exe"
del /f "%JAVA32_PATH%\javaw.exe"
mklink "%JAVA32_PATH%\javaw.exe" "%JAVA_HOME%\bin\javaw.exe"
set JAVA_PATH=C:\Program Files\Common Files\Oracle\Java\javapath
del /f "%JAVA_PATH%\java.exe"
mklink "%JAVA_PATH%\java.exe" "%JAVA_HOME%\bin\java.exe"
del /f "%JAVA_PATH%\javaw.exe"
mklink "%JAVA_PATH%\javaw.exe" "%JAVA_HOME%\bin\javaw.exe"
echo =================================================================================================
echo 已切换到Java%JAVA_VERSION%
java -version
pause
goto exit
:exit